Introduction:
After releasing my previous Tiny DOS-Intro Album "Bakers' Dozen" the previous year at Inercia Demoparty so I was fully commited to supporting the party again and promised psenough that I would release a new Tiny Intro Album at Inercia 2024.
Since i'm always looking for new challenge, I figured I'd try to one-up my Bakers' Dozen album and do a 128 byte intro album, meaning I was limited to just doing 32, 16 and 8 byte intros. I already had a few unreleased intros around in these In the end I managed to build a new album with 5 completely new/original intros, along with 2 previous restarfallbonus sizes and used those together with some additional material to fill the album.
intros. Lets take a closer look at the intro...
Starfall (32 Bytes, DOS):
This is an diagonal automaton effect with a custom blue palette and some PC speaker noise.
org 100h
; Initialise video and generate blue palette
mov al,13h
lds bx,[bx]
palloop:
int 10h
mov ax,1010h
inc bx
loop palloop
frameloop:
; automaton calculation
lodsb
cbw
xor al,ah
or al,[si-319]
dec ax
; write color
mov [si],al
imul si,byte 81 ; Jump to different offset
out 61h,al ; PC Speaker out
jmp frameloop
Levtech (32 Bytes, DOS):
This is my fresh take on a minsky/ifs/levi hybrid fractal in 32 bytes. It is using the BIOS function for plotting the pixels along with a grayscale palette. I like it because its different/fresh enough from dragon, leaf and levi fractals to be its own thing.
org 100h
frameloop:
xor al,0x13 ; init video and mess with colorvalue
int 0x10
; minskyesque fractal calc
sub cl,dl
sar cl,1
add dl,cl
mov al,[fs:0x46c] ; al=timer (4 bytes!!!)
add al,cl ; add fractalvalue
jpo storepixel
; swap x/y + add offset
xchg dl,cl
neg dl
add dl,0x70
storepixel:
and al,0x7 ; cap colorvalue
mov ah,0xc ; draw pixel function
jmp frameloop
Superstructure (16 Bytes, DOS):
Doing graphical intros in 16 bytes is kind of challenge, especially when you have some animation/moving elements.
In this intro the videomode init and BIOS setPixel function are rolled intro the same loop, with the color being within the gray colorvalues due to the aaa and adc al,13h. The animation is done by updating the Y-coord register (inc dx in an outside loop whilst CX is being decreased due to the loop frameloop.
org 100h
frameloop:
adc al,0x13
int 0x10
aaa
add ch,al
add ch,al
mov ah,0x0c
loop frameloop
inc dx
jmp frameloop
Network (16 Bytes, DOS):
Another 16 byte graphical intro which I had laying around for a while now. Unlike Superstructure this one was was achieved experimenting from a minimal graphical setup. After some experimentation I ended up with this server-network kind of of setup and coloring. Again the video init and setPixel are rolled into the same loop.
org 100h
frameloop:
adc al, 13h
int 10h
sbb bx, bp
xlatb
rol ax,cl
adc cx, ax
aas
mov ah, 0ch
jmp frameloop
Ribbons (16 Bytes, DOS):
Another experimental 16 byte intro, and my least favorite on the album. Originally this slot was reserved for another intro, but I couldnt get that one down to 16 bytes sadly, so consider this a filler intro ;-)
org 100h
les bx,[bx]
add al,13h
int 10h
frameloop:
scasb
stosb
shld ax,cx,1
adc cx,si
jmp frameloop
Bonus: Oscill8r (8 Bytes, DOS):
This intro was originally released at Lovebyte 2024 and i think has a nice pulsating effect that uses the XLATB flip-flop. The SCASW is mostly there to get the les ax,[si] to be within 0xB800 range ;-).
les ax,[si]
frameloop:
xlatb ; 0xD7
scasw ; 0xAB
add di,ax
jmp frameloop
Bonus: Luck and Love (8 Bytes, DOS):
Originally released at Lovebyte 2023, this is another implementation of a 'bit-roller' effect, similar to e.g. the 8-byte Max8room intro using the XLAT flipflop trick. This intro requires the two opcodes after the LES AX,[SI] to be within 0xb800 range to work.
Thanks to Blossom for the title.
les ax,[si]
frameloop:
aaa ; 0x37
stosb ; 0xAA
scasw
xlatb
jmp frameloop
Conclusion:
It took a lot of hard work to complete this in time for Inercia 2024, just because of the amount of original content needed for this collection, but i'm glad that I just made it in time for the party.
For more information about this Tiny Intro album and its content, you can find it at demozoo
- Enjoy!