Introduction:
NOVA Demoparty in the UK is one of only a few events out there that hosts both 128 Byte and 256 Byte Intro competitions. So I wanted to support competitions again.
Nexus (256 Bytes, MicroW8):
The original idea of this intro was done about a year ago, when I tried to get something using a menger fractal going and see if I was able to get it performant enough. Because of the (code) complexity of this shape, I haven't been able to do a full menger yet in the very small sizes, but I eventually did end up with what eventually became Nexus.
Visuals:
This intro uses something that can be considered a menger-like fractal at its core, which is then sheered, scaled and mirrored in such a way to look like a futuristic hanger, with the camera swaying in various ways through the structure..
Here is the pseudo code I've used to generate the base-sdf the visuals:
px = (abs(v)-abs(u)) * z;
py = v * z;
pz = z + t / 2.0;
dist = 0.0;
for i=0,3 do {
newdist = min(max(py,px),min(max(py,pz),max(px,pz))) - 2.0;
dist=max(newdist,dist);
px = abs(2.0 - (sin(s * px) * 3.0) );
py = abs(1.0 - (sin(s * py) * 3.0) );
pz = abs(2.0 - (sin(s * pz) * 3.0) );
}
By using a non-conventional way of doing domain repetition you might be able to notice that in the intro the different hanger cutouts are not uniform and disorted in all directions. Given the complexity of the SDF even with only 3 iteration steps the rendering is speed up a little by skipping scanlines and only drawing half of the screen.
Texturing and Coloring:
Once we have a final distance for our pixel, I wanted to spend a little more of the sizebudget in generating a somewhat more complex 'texture' for the walls and floors of the hanger. Here we are blending the depth and texture again with appropriate color ranges that will give us that perfect sci-fi look.
Audio:
This intro uses a custom softsynth in the 'snd' function callback. The soundscape for this one consists of 2 layers of stacked sawtooths. A base layer with a droning sound, with a second melody layer on top that cointains hard volume cuts to the notes that will give it a sort of a clicky rhythm, a technique that I call the 'clickdrum'. Obviously a proper kick is preferefered to a click, but since we already spent the vast majority of the size budget on the visuals, this was the best compromise I could think of.
; given t as sampleoffset
noteTime = t / noteDivisor;
for n=0,numSoundlayers,stepsize do
// calculate a small oscillation between the layers
osc = (fmod(n*n,1.0) / 192 - 1);
n1 = t * osc / 1760; // basedrone
n2 = (((2-T#%4)*t) as f32) * osc / 880; // melody
// use sawtooths for both
v = v + fmod(n1,2.0);
v = v - fmod(n2,2.0);
end
// Here we control the final volume fade-in / fade-out
v = v * mastervolume / 192.0;
Here the frequencies n1, n2 are then added as oscillated sawwaves (n1,n2) a combination of additive and subtractive synthesis and finally divided down to a float samplevalue using our mastervolume fade.
Glaze (128 Bytes, DOS):
This intro was actually an old DOS intro from back in 2023/2024 that hadn't been released yet. Therefore, I don't remember the specifics that went into it very well, other than it is using the FPU to calculate a tilted perspective plane (using sheering rather than actual 2D rotation) and then is using the project UV coordinates to generate an animated fractal structure for the ice. The fractal structure is similar, but more flexible/less optimise to the one used in Fractured.
Here is the commented sourcecode for those that are interested.
org 100h
start:
scalevalue dw 13h
; init video and palette
mov al,13h
palloop:
int 10h
sub dh,4
sub ch,2
inc bx
mov ax,1010h
loop palloop
frameloop:
; calculate x/y from offset
xor bx,bx
les ax,[bx]
mov ah,0xcc
mul di
sub dx,648Ch
; perspective plane
pusha
fninit
fild word [bx-14] ; c
fidiv word [bx-16] ; a
fsin ; sa
fsincos ; sin cos a
fild word [bx-9] ; x sin cos a
fmulp st2 ; sin x*cos a
fimul word [bx-8] ; y*sin x*cos a
faddp ; y*sin+x*cos a
fidiv word [si] ;(scalevalue)]
fild word [bx-9] ; x
fdiv st1
fistp word [bx-8]
fild word [byte si + (floorval-256)]
fdiv st1
fistp word [bx-10]
popa
; check sky
mov ax,bx
sar ax,5
js drawpixel
; move plane
add bx,bp
; animate ice
mov dh,bl
salc
mov bx,bp
sar bx,3
; ice-shape fractal
mov cl,15
fractalloop:
cmp dl,bl
jb nosub
inc ax
nosub:
mov ah,dh
sar ah,1
sub dh,dl
add dl,ah
loop fractalloop
drawpixel:
and al,15
inc ax
stosb
inc di
inc di
skippy:
jnz frameloop
inc bp
; relaxing piano
mov dx,0x330
imul ax,bp,77
aam 0xDE
out dx,al
jmp skippy
; constants
floorval dw 32767
Conclusion:
I was happy to see that both intros were received well at the party and had a great audience response.
For more information, you can check out the intros at demozoo: Glaze (2026) and Nexus (2026)